Quest goes MODBUS (Arduino Slave für Artisan)

Hallo,

ich hatte es ja hier schon angedroht: mein Quest wird MODBUS-fähig! Eigentlich ist es ja nicht der Quest, sondern die Arduino-Steuerung, so ist die MODBUS-Lösung ev. eine Alternative für Anwender, die über Artisan einen beliebigen Röster steuern wollen.
Mein Setup: 2 Thermoelemente Typ K (ET, BT) werden ausgelesen, Werte für die Heizungssteuerung und die Lüftersteuerung (jeweils 0-100% Leistung) werden zurückgeschrieben.
Für die Heizungssteuerung gibt es eine Steuerung mit einem SSR, es wird in einem Intervall von 2 Sekunden je nach Leistungswert anteilig ein- und ausgeschaltet. Abtastintervall für Artisan ist auch 2s.
Die Lüftersteuerung geschieht über einen Dimmer von Kemo, der mittels PWM angesteuert wird.
An Hardware wird benötigt:

• Arduino (hier: Nano) + Netzteil (altes Handyladegerät reicht)
  
• 2 MAX6675-Module zum Auslesen der Temperaturen
• Umsetzer von RS232 auf RS485 für den Arduino (MAX485)
• Umsetzer von USB auf RS485 für das Notebook
• Dimmer
• SSR

Die programmtechnische Umsetzung habe ich mit der Bibliothek ModbusSlave.h gemacht. Anspruch war nicht, einen vollständigen MODBUS-Slave zu implementieren, sondern nur genau die für Artisan benötigten Funktionen. Dazu habe ich ein mitgeliefertes Beispielprogramm abgestrippt.
Anbei der Code für die besprochenen Funktionen:


Und dazu die nötigen Einstellungen in Artisan:


Funktioniert soweit gut, für den Einbau werde ich noch ein lokales Display vorsehen und ein Relais, das von lokaler Steuerung des Quest auf Remote Modus durch Artisan umstellt.

Gruß, Andreas

 

Hallo Uwe,

die gezeigte Lösung arbeitet schon mit einer Nachkommastelle! Im Programm in Zeile 25 und 26 sieht man, dass die Temperaturen vor der Umwandlung in Integer mit 10 multipliziert werden. Der entsprechende (Rück-)Teiler von 1/10 steht in den Anschlusseinstellungen in Artisan bei den Eingängen - so bekomme ich eine Nachkommastelle. Man könnte auch 2 einstellen (es gibt auch den Teiler 1/100 in Artisan), aber mit einer Stelle sieht das bei mir ganz gut aus. Die Genauigkeit der Temperaturmessung gibt ja schon die erste Nachkommastelle kaum her, ist mehr für die Optik.

Gruß, Andreas

 

Hallo Uwe,

die beiden Umsetzer etablieren eine RS485-Schnittstelle zwischen PC und Arduino. Prinzipiell müsste es auch über die normale serielle Schnittstelle funktionieren, aber die RS485 ist die 'native' MODBUS-Schnittstelle und während meiner Tests mit verschiedenen Bibliotheken hatte ich Stabilitätsprobleme mit der normalen.
Ein kurzer Test ergab: mein Programm läuft auch über die normale serielle Schnittstelle via USB, allerdings mit Einschränkungen:
- Bei jeden Einschalten des Röstoskops wird die Schnittstelle (und damit auch der Nano) resetted.
- Bei Kommunikationsproblemen wird auch resetted (Timeout, etc.).
Da beim Reset durch die Kopplung mit der Spannungsversorgung die aktuellen Stellwerte verloren gehen, ist das keine Alternative für mich. Ev. gibt es da besser geeignete Bibliotheken (die hier verwendete erwartet RS485!)?
Die Artisan Konfiguration kannst Du aus meinem zweiten Bild ablesen, den Sketch zum rauskopieren hänge ich mal unten an...

Gruß, Andreas

#include <ModbusSlave.h>
#include <max6675.h>

#define CTRL_PIN 2
#define LueftPin 3
#define ktcCS1Pin 5
#define ktcCS2Pin 6
#define ktcSOPin 8
#define ktcCLKPin 10
#define HeizPin 11

Modbus slave(1, CTRL_PIN); //MODBUS Slave #1, ControlPin ist 2

MAX6675 ktcET(ktcCLKPin, ktcCS1Pin, ktcSOPin); //Thermoelement ET
MAX6675 ktcBT(ktcCLKPin, ktcCS2Pin, ktcSOPin); //Thermoelement BT

float BT = -1.0; //Bohnentemperatur
float ET = -1.0; //Trommeltemperatur oberhalb der Bohnen
uint8_t heiz = 0; //Stellgröße für Heizung (0-100%)
uint8_t lueft = 0; //Stellgröße für Lüfter (0-100%)

long StellInt = 2000; //Intervall für Wellenpaketsteuerung Heizungs-SSR
long UHighInt = 0; //Zeit(-anteil) HIGH für Heizung
long StellMillis = 0; //Basis für Wellenpaketsteuerung

uint8_t readMemory(uint8_t fc, uint16_t address, uint16_t length) { // Handler Read (FC=03)
if (address == 1) slave.writeRegisterToBuffer(0, (uint16_t)(BT*10.0));
if (address == 2) slave.writeRegisterToBuffer(0, (uint16_t)(ET*10.0));
return STATUS_OK;
}

uint8_t writeMemory(uint8_t fc, uint16_t address, uint16_t length) {// Handler Write (FC=06, FC=16)
if (address == 1) heiz = slave.readRegisterFromBuffer(0);
UHighInt = heiz*StellInt/100;
if (address == 2) lueft = slave.readRegisterFromBuffer(0);
return STATUS_OK;
}

void setup() {
pinMode(CTRL_PIN, OUTPUT); // RS485 control Pin
pinMode(LueftPin, OUTPUT); // Ausgang für Lüftersteuerung mit PWM -> Kemo
pinMode(HeizPin, OUTPUT); // Ausgang Wellenpaketsteuerung für Heizung

// register handler functions into the modbus slave callback vector.
slave.cbVector[CB_READ_REGISTERS] = readMemory;
slave.cbVector[CB_WRITE_REGISTERS] = writeMemory;

Serial.begin(57600); // Initialisierung Serial mit 57600 Baud
slave.begin(57600); // Initialisierung slave mit 57600 Baud
}

void loop() {
long aktMillis = millis(); //aktueller Clocktick

ET = ktcET.readCelsius(); //ET auslesen
BT = ktcBT.readCelsius(); //BT auslesen

slave.poll(); //Abfrage und Behandlung von MODBUS-Kommandos

//Stellgrößen ausgeben
if (aktMillis - StellMillis <= UHighInt) digitalWrite(HeizPin,HIGH); else digitalWrite(HeizPin,LOW);
if (aktMillis - StellMillis >= StellInt) StellMillis = aktMillis;
analogWrite(LueftPin,lueft*2.55);
}

 

Hallo Uwe,

der Haken ist bei mir (und wohl auch standardmässig) gesetzt und die Nachkommastellen werden korrekt angezeigt.

Gruß, Andreas

Edit: Ich sehe gerade, dass Dein Problem wohl im Arduino-Sketch liegt: Die Integer-Umwandlung muss nach der Multiplikation erfolgen, da steht eine Klammer falsch! Probier mal das:

au16data[2] = (uint16_t) (thermocouple.readCelsius()*100);

 

Hallo,

merke gerade, dass der oben gezeigte Sketch zu eingefrorenen Temperaturen führt... Grund ist, dass die MAX6675 einfrieren, wenn man sie schneller als alle ~ 220ms abfragt (der Sketch oben enthält nicht meinen Debug-Code mit seriellen Ausgaben, der eine entsprechende Verzögerung zwischen den Temperaturabfragen erzeugt hatte ). Wer den Sketch also nachempfinden möchte: Sicherstellen, dass mindestens 220ms zwischend den readCelsius() - Aufrufen liegen (z.B. mit delay(250) oder Verschieben in die Handler-Funktion readMermory()).

Gruß, Andreas